adda, Sql Server - rextester

Language: Layout:

CREATE TABLE tab1(a INT, b INT);

INSERT INTO tab1 VALUES (1,1),(1,1),(1,1),(2,3);
GO

CREATE PROCEDURE dbo.remove_duplicates
    @tab_name SYSNAME
    ,@debug BIT = 0
AS
BEGIN
    SET NOCOUNT ON;
    -- TODO: validation if table exists and error raising
    
    DECLARE @sql NVARCHAR(MAX) = 
       'WITH cte AS
        (
            SELECT *, rn = ROW_NUMBER() OVER(PARTITION BY <cols> ORDER BY (SELECT 1))
            FROM <tab_placeholder>
        )
        DELETE FROM cte
        WHERE rn <> 1;';
        
    DECLARE @cols NVARCHAR(MAX) = STUFF((SELECT ',' +  column_name
                                        FROM INFORMATION_SCHEMA.COLUMNS
                                        WHERE TABLE_NAME = @tab_name
                                          AND TABLE_SCHEMA = 'dbo'
                                        FOR XML PATH('')), 1, 1, '');    
        
     
    
    SET @sql = REPLACE(@sql, '<tab_placeholder>', QUOTENAME(@tab_name));
    SET @sql = REPLACE(@sql, '<cols>', @cols);
    
    IF @debug  = 1 SELECT @sql;
        
    EXEC dbo.sp_executesql @sql;

END
GO

EXEC  dbo.remove_duplicates 'tab1', 1;

SELECT *
FROM  tab1;

View schema
Execution time: 0,06 sec, rows selected: 2, rows affected: 4, absolute service time: 0,23 sec