Задание 27 (окончательный вариант) эффект и неэффект, Pascal

Задание 27 (окончательный вариант) эффект и неэффект

const 
    delta = 0; // заменяется на любую разумную величину 
               // от нуля до количества элементов минус 1.

var
    n, i, j, s, s11, sn, x : integer;
    m : array [0..delta] of integer; // массив для эффективной программы
    a : array [0..100] of integer; // массив для неэффективной программы

begin
    writeln('Расстояние между числами определяется параметром delta внутри программы');
    
    s := 0; // количество пар
    s11 := 0; // количество чисел, кратных одиннадцати 
    sn := 0; // количество чисел, не кратных одиннадцати
    
    writeln ('эффективный алгоритм: введите количество чисел:');
    readln (n);
    writeln ('эффективный алгоритм: введите числа:');
    for i := 0 to delta do  
    begin 
      readln (x); 
      m[i] := x;
      a[i] := x // запоминаем для неэффективного алгоритма
    end;
    
    for i := delta + 1 to n - 1 do
    begin
        // считываем очередное число x и вместе с нулевым элементом m[0] определяпем пару 
        // всего возможно 4 варианта для m[0] и x:
        // кратно-кратно
        // кратно-некратно
        // некратно-кратно
        // некратно-некратно
        readln (x);
        a[i] := x; // запоминаем для неэффективного алгоритма
        if (m[0] mod 11 <> 0) and (x mod 11 <> 0) then
        begin
            sn := sn + 1;
            s := s + s11
        end
        else if (m[0] mod 11 = 0) and (x mod 11 = 0) then
        begin
            s11 := s11 + 1; 
            s := s + s11 + sn
        end
        else if (m[0] mod 11 = 0) and (x mod 11 <> 0) then
        begin
            s11 := s11 + 1;
            s := s + s11
        end
        else if (m[0] mod 11 <> 0) and (x mod 11 = 0) then
        begin
            sn := sn + 1;
            s := s + s11 + sn
        end;
           
        for j:= 0 to delta - 1 do // сдвигаем элементы массива на один влево
        begin
            m[j] := m[j+1];
        end;
        m[delta] := x; // не забываем в последний элемент массива записать x
    end;
    writeln('Количество пар=', s); // выводим ответ
    
// Неэффективный алгоритм    
    writeln ('неэффективный алгоритм:');
//    readln (n);
    s := 0; 
//    writeln ('неэффективный алгоритм: введите числа, как при первом вводе:');
//    for i := 0 to n - 1 do
//    begin
//        readln (x); a[i] := x 
//    end;
    
    for i := 0 to n - delta -1 do
    begin
        for j := i + delta + 1 to n-1 do
        begin
            if a[i]*a[j] mod 11 = 0 then s := s + 1
        end;
    end;
    writeln('Количество пар=', s); // выводим ответ
end.


run \| edit \| history \| help	0

λ

                                      .NET NoSQL database for rapid development